From 6517ca329d6ad96a0d5698b11f62dd57bb65da0a Mon Sep 17 00:00:00 2001
From: 514fpv <koishi@514fpv.one>
Date: Tue, 2 Jan 2024 14:49:06 +0800
Subject: [PATCH] feat(fs): add configuration for xfs, ext4, btrfs

---
 faucet/fs/btrfs.nix   | 22 +++++++++++
 faucet/fs/default.nix | 87 +++++++++++++++++++++++++++++++++++++++++++
 faucet/fs/ext4.nix    | 10 +++++
 faucet/fs/xfs.nix     | 11 ++++++
 4 files changed, 130 insertions(+)
 create mode 100644 faucet/fs/btrfs.nix
 create mode 100644 faucet/fs/default.nix
 create mode 100644 faucet/fs/ext4.nix
 create mode 100644 faucet/fs/xfs.nix

diff --git a/faucet/fs/btrfs.nix b/faucet/fs/btrfs.nix
new file mode 100644
index 00000000..f8252be3
--- /dev/null
+++ b/faucet/fs/btrfs.nix
@@ -0,0 +1,22 @@
+{ pkgs
+, lib
+, config
+, ... }: with lib; let
+  cfg = config.faucet.fs;
+in {
+  options.faucet.fs.btrfs = {
+    options = mkOption {
+      type = with types; listOf str;
+      default = [ "noatime" "compress=zstd" ];
+      description = "btrfs mount options";
+    };
+  };
+
+  config = mkIf (cfg.type == "btrfs") {
+    fileSystems."/nix" =
+    { inherit (cfg.btrfs) options;
+      device = "/dev/disk/by-uuid/${cfg.store}";
+      fsType = "btrfs";
+    };
+  };
+}
diff --git a/faucet/fs/default.nix b/faucet/fs/default.nix
new file mode 100644
index 00000000..6cbdb9e7
--- /dev/null
+++ b/faucet/fs/default.nix
@@ -0,0 +1,87 @@
+{ pkgs
+, lib
+, config
+, ... }: with lib; let
+  cfg = config.faucet.fs;
+in {
+  imports = [
+    ./ext4.nix
+    ./xfs.nix
+    #./bcachefs.nix
+    ./btrfs.nix
+  ];
+
+  options.faucet.fs = {
+    type = mkOption {
+      type = with types; enum [ "ext4" "xfs" "bcachefs" "btrfs" ];
+      default = "bcachefs";
+      description = "filesystem type to use for persistent state storage";
+    };
+    store = mkOption {
+      type = with types; str;
+      description = "UUID/dataset of nix store backing device";
+    };
+    esp = {
+      enable = mkEnableOption "EFI system partition" // { default = true; };
+      uuid = mkOption {
+        type = with types; str;
+        default = "cafebabe";
+        description = "vfat serial number of EFI system partition";
+      };
+    };
+    extPersist = {
+      enable = mkEnableOption "external persist filesystem";
+      # this wraps the standard fileSystems module
+      # since some attrs have to be unconditionally set
+      device = mkOption {
+        default = null;
+        type = with types; nullOr str;
+        description = "Location of the device.";
+      };
+      fsType = mkOption {
+        default = "auto";
+        type = with types; str;
+        description = "Type of the file system.";
+      };
+      options = mkOption {
+        default = [ "defaults" ];
+        description = "Options used to mount the file system.";
+        type = with types; nonEmptyListOf str;
+      };
+    };
+    cryptsetup = {
+      enable = mkEnableOption "full disk encryption device early setup";
+      allowDiscards = mkEnableOption "allow discards via device-mapper" // { default = true; };
+      bypassWorkqueues = mkEnableOption "bypass dm-crypt's internal workqueues" // { default = true; };
+      uuids = mkOption {
+        type = with types; attrsOf str;
+        description = "device-mapper name to encrypted block device UUID mapping";
+      };
+    };
+  };
+
+  config = {
+    fileSystems."/" =
+    { device = "rootfs";
+      fsType = "tmpfs";
+      options = [ "size=2G" "mode=755" ];
+    };
+    fileSystems."/boot" = mkIf cfg.esp.enable
+    { device = "/dev/disk/by-uuid/${cfg.esp.uuid}";
+      fsType = "vfat";
+    };
+    fileSystems."/nix/persist" = mkIf cfg.extPersist.enable
+    { inherit (cfg.extPersist) device fsType options;
+      neededForBoot = true;
+      depends = "/nix";
+    };
+
+    services.fstrim.enable = mkIf ((cfg.type == "ext4") || (cfg.type == "xfs")) true;
+
+    boot.initrd.luks.devices = mkIf cfg.cryptsetup.enable (
+    mapAttrs' (name: uuid: nameValuePair "luks-${name}" {
+      inherit (cfg.cryptsetup) allowDiscards bypassWorkqueues;
+      device = "/dev/disk/by-uuid/${uuid}";
+    }) cfg.cryptsetup.uuids);
+  };
+}
diff --git a/faucet/fs/ext4.nix b/faucet/fs/ext4.nix
new file mode 100644
index 00000000..aeaafb18
--- /dev/null
+++ b/faucet/fs/ext4.nix
@@ -0,0 +1,10 @@
+{ lib
+, config
+, ... }: with lib; let
+  cfg = config.faucet.fs;
+in mkIf (cfg.type == "ext4") {
+  fileSystems."/nix" =
+  { device = "/dev/disk/by-uuid/${cfg.store}";
+    fsType = "ext4";
+  };
+}
diff --git a/faucet/fs/xfs.nix b/faucet/fs/xfs.nix
new file mode 100644
index 00000000..03025993
--- /dev/null
+++ b/faucet/fs/xfs.nix
@@ -0,0 +1,11 @@
+{ lib
+, config
+, ... }: with lib; let
+  cfg = config.faucet.fs;
+in mkIf (cfg.type == "xfs") {
+  # NOTE: -m reflink=1
+  fileSystems."/nix" =
+  { device = "/dev/disk/by-uuid/${cfg.store}";
+    fsType = "xfs";
+  };
+}