feat(headless): add headless module

home/headless/home.nix

@@ -0,0 +1,24 @@
+{ pkgs
+, lib
+, config
+, ... }: with lib; let
+  cfg = config.passthrough.headless;
+in mkIf (cfg.enable != null) {
+  wayland.windowManager.sway.config = {
+    output = {
+      ${cfg.enable}.pos = "0 0";
+      HEADLESS-1 = cfg.output;
+    };
+
+    startup = [ { command = "swaymsg create_output && swaymsg output HEADLESS-1 disable"; } ];
+  };
+
+  home.packages = [ (pkgs.writeShellScriptBin "headless" ''
+    swaymsg output HEADLESS-1 enable
+    ${pkgs.wayvnc}/bin/wayvnc \
+      --output=HEADLESS-1 \
+      ${cfg.extraArgs} \
+      ${cfg.host} ${toString cfg.port}
+    swaymsg output HEADLESS-1 disable
+  '') ];
+}

home/headless/nixos.nix

@@ -0,0 +1,51 @@
+{ pkgs
+, lib
+, config
+, ... }: with lib; let
+  cfg = config.home.headless;
+in {
+  options.home.headless = {
+    enable = mkOption {
+      type = with types; nullOr str;
+      default = null;
+      description = "a headless, remotely viewed sway display";
+    };
+
+    output = mkOption {
+      type = with types; attrsOf str;
+      default = {
+        # pixel tablet
+        mode = "2560x1600";
+        scale = "2";
+        pos = "1920 0";
+      };
+      description = "headless display configuration";
+    };
+
+    host = mkOption {
+      type = with types; str;
+      default = "0.0.0.0";
+      description = "wayvnc listen host";
+    };
+
+    port = mkOption {
+      type = with types; port;
+      # utility port
+      default = 1300;
+      description = "wayvnc listen port";
+    };
+
+    extraArgs = mkOption {
+      type = with types; str;
+      default = "--max-fps=60";
+      description = "extra wayvnc args";
+    };
+  };
+
+  config = {
+    users.homeModules = [
+      # this module passes headless configuration to home-manager
+      { passthrough.headless = cfg; }
+    ];
+  };
+}